Take the 2-minute tour ×
Server Fault is a question and answer site for professional system and network administrators. It's 100% free, no registration required.

Simple task:

Move all the content of the directory c:\Users\files\Desktop\test 2 to c:\Users\files\Desktop\test 1

C:\admin\temp>robocopy "c:\Users\files\Desktop\test 2" "c:\Users\files\Desktop\test" *.* /S /MOVE

Sounds reasonable, but now, the directory c:\Users\files\Desktop\test 2 gets removed too. Is there a switch to just move the CONTENT without the removing directory itself?

share|improve this question
    
Why does Robocopy have to be different to what? –  John Gardeniers Aug 6 '10 at 10:25
    
screencast.com/t/YTkwODIzZT –  perler Aug 6 '10 at 18:42
    
What about robocopy test1 test2 ... && mkdir test2 –  jftuga Feb 6 '11 at 3:21
add comment

10 Answers 10

I have been trying to do the same from a network share.

SET MoveDirSource=\\Server\Folder
SET MoveDirDestination=Z:\Folder

Here are my findings and solution from tests on a Windows 7 machine.

Suggestion:

ROBOCOPY "%MoveDirSource%" "%MoveDirDestination%" /MOVE /E

Problem: Moves source folder.

Suggestion:

ROBOCOPY "%MoveDirSource%" "%MoveDirDestination%" /MOVE /E /XD "%MoveDirSource%"

Problem: Still moves source folder.

Suggestion:

ROBOCOPY "%MoveDirSource%" "%MoveDirDestination%" /MOV /E

Problem: Leaves empty folder structure behind in source folder.

Working solution:

MKDIR "%MoveDirDestination%"
FOR    %%i IN ("%MoveDirSource%\*") DO           MOVE /Y "%%i" "%MoveDirDestination%\%%~nxi"
FOR /D %%i IN ("%MoveDirSource%\*") DO ROBOCOPY /MOVE /E "%%i" "%MoveDirDestination%\%%~nxi"

First two lines move the top level files, the third moves the folders. Note the use of double %% is for usage in a batch file, pasting into a commandline needs these changed to a single percentage mark.

share|improve this answer
add comment

Have you tried the /MOV option?

           /MOV :: MOVe files (delete from source after copying).

F:>robocopy /?


ROBOCOPY :: Robust File Copy for Windows

Started : Fri Aug 06 11:51:26 2010

          Usage :: ROBOCOPY source destination [file [file]...] [options]

         source :: Source Directory (drive:\path or \\server\share\path).
    destination :: Destination Dir  (drive:\path or \\server\share\path).
           file :: File(s) to copy  (names/wildcards: default is "*.*").

::
:: Copy options :
::
             /S :: copy Subdirectories, but not empty ones.
             /E :: copy subdirectories, including Empty ones.
         /LEV:n :: only copy the top n LEVels of the source directory tree.

             /Z :: copy files in restartable mode.
             /B :: copy files in Backup mode.
            /ZB :: use restartable mode; if access denied use Backup mode.
        /EFSRAW :: copy all encrypted files in EFS RAW mode.

/COPY:copyflag[s] :: what to COPY for files (default is /COPY:DAT).
                   (copyflags : D=Data, A=Attributes, T=Timestamps).
                   (S=Security=NTFS ACLs, O=Owner info, U=aUditing info).

       /DCOPY:T :: COPY Directory Timestamps.

           /SEC :: copy files with SECurity (equivalent to /COPY:DATS).
       /COPYALL :: COPY ALL file info (equivalent to /COPY:DATSOU).
        /NOCOPY :: COPY NO file info (useful with /PURGE).

        /SECFIX :: FIX file SECurity on all files, even skipped files.
        /TIMFIX :: FIX file TIMes on all files, even skipped files.

         /PURGE :: delete dest files/dirs that no longer exist in source.
           /MIR :: MIRror a directory tree (equivalent to /E plus /PURGE).

           /MOV :: MOVe files (delete from source after copying).
          /MOVE :: MOVE files AND dirs (delete from source after copying).

 /A+:[RASHCNET] :: add the given Attributes to copied files.
 /A-:[RASHCNET] :: remove the given Attributes from copied files.

        /CREATE :: CREATE directory tree and zero-length files only.
           /FAT :: create destination files using 8.3 FAT file names only.
           /256 :: turn off very long path (> 256 characters) support.

         /MON:n :: MONitor source; run again when more than n changes seen.
         /MOT:m :: MOnitor source; run again in m minutes Time, if changed.

  /RH:hhmm-hhmm :: Run Hours - times when new copies may be started.
            /PF :: check run hours on a Per File (not per pass) basis.

         /IPG:n :: Inter-Packet Gap (ms), to free bandwidth on slow lines.

            /SL :: copy symbolic links versus the target.

        /MT[:n] :: Do multi-threaded copies with n threads (default 8).
                   n must be at least 1 and not greater than 128.
                   This option is incompatible with the /IPG and /EFSRAW options.
                   Redirect output using /LOG option for better performance.

::
:: File Selection Options :
::
             /A :: copy only files with the Archive attribute set.
             /M :: copy only files with the Archive attribute and reset it.
/IA:[RASHCNETO] :: Include only files with any of the given Attributes set.
/XA:[RASHCNETO] :: eXclude files with any of the given Attributes set.

/XF file [file]... :: eXclude Files matching given names/paths/wildcards.
/XD dirs [dirs]... :: eXclude Directories matching given names/paths.

            /XC :: eXclude Changed files.
            /XN :: eXclude Newer files.
            /XO :: eXclude Older files.
            /XX :: eXclude eXtra files and directories.
            /XL :: eXclude Lonely files and directories.
            /IS :: Include Same files.
            /IT :: Include Tweaked files.

         /MAX:n :: MAXimum file size - exclude files bigger than n bytes.
         /MIN:n :: MINimum file size - exclude files smaller than n bytes.

      /MAXAGE:n :: MAXimum file AGE - exclude files older than n days/date.
      /MINAGE:n :: MINimum file AGE - exclude files newer than n days/date.
      /MAXLAD:n :: MAXimum Last Access Date - exclude files unused since n.
      /MINLAD:n :: MINimum Last Access Date - exclude files used since n.
                   (If n < 1900 then n = n days, else n = YYYYMMDD date).

            /XJ :: eXclude Junction points. (normally included by default).

           /FFT :: assume FAT File Times (2-second granularity).
           /DST :: compensate for one-hour DST time differences.

           /XJD :: eXclude Junction points for Directories.
           /XJF :: eXclude Junction points for Files.

::
:: Retry Options :
::
           /R:n :: number of Retries on failed copies: default 1 million.
           /W:n :: Wait time between retries: default is 30 seconds.

           /REG :: Save /R:n and /W:n in the Registry as default settings.

           /TBD :: wait for sharenames To Be Defined (retry error 67).

::
:: Logging Options :
::
             /L :: List only - don't copy, timestamp or delete any files.
             /X :: report all eXtra files, not just those selected.
             /V :: produce Verbose output, showing skipped files.
            /TS :: include source file Time Stamps in the output.
            /FP :: include Full Pathname of files in the output.
         /BYTES :: Print sizes as bytes.

            /NS :: No Size - don't log file sizes.
            /NC :: No Class - don't log file classes.
           /NFL :: No File List - don't log file names.
           /NDL :: No Directory List - don't log directory names.

            /NP :: No Progress - don't display percentage copied.
           /ETA :: show Estimated Time of Arrival of copied files.

      /LOG:file :: output status to LOG file (overwrite existing log).
     /LOG+:file :: output status to LOG file (append to existing log).

   /UNILOG:file :: output status to LOG file as UNICODE (overwrite existing log).
  /UNILOG+:file :: output status to LOG file as UNICODE (append to existing log).

           /TEE :: output to console window, as well as the log file.

           /NJH :: No Job Header.
           /NJS :: No Job Summary.

       /UNICODE :: output status as UNICODE.

::
:: Job Options :
::
   /JOB:jobname :: take parameters from the named JOB file.
  /SAVE:jobname :: SAVE parameters to the named job file
          /QUIT :: QUIT after processing command line (to view parameters).
          /NOSD :: NO Source Directory is specified.
          /NODD :: NO Destination Directory is specified.
            /IF :: Include the following Files.
share|improve this answer
2  
yes, but this moves JUST the files and let the directories untouched, i want to move the files and the directories but keep the parent directory itself in place –  perler Aug 6 '10 at 18:39
    
That would be a.... copy? Sorry - don't get what you're trying to do. *If it is just a copy, then use /S –  Guy Aug 11 '10 at 17:56
    
-1 answer doesn't address the question asked –  Chris Marisic Feb 3 '11 at 18:54
1  
@Chris. A little harsh methinks. The answer was valid apart from the "parent directory" requirement, and I did ask for clarification which that was only availanble after I posted the answer. Using my answer you could use the /XD or /XA parameter. –  Guy Feb 4 '11 at 12:44
1  
This is actually the perfect answer to this question. Use robocopy with the "/mov" switch (not the "/move" switch) and target the parent directory. Voila!! –  John Homer Mar 15 '12 at 15:23
show 1 more comment

You can do this by creating a placeholder file in the directory you don't want to delete, and then instructing robocopy to exclude the file using /XF

Since the file is excluded, it won't get moved, and the directory won't get deleted.

For details, see that other site: http://www.experts-exchange.com/OS/Microsoft_Operating_Systems/Windows/XP/Q_24306678.html (and scroll down to the bottom, etc, etc).

share|improve this answer
1  
This doesn't seem to be the case, I have the bat file itself in the directory i want to copy, the bat file is excluded and robocopy still tries to delete the folder (and fails because the bat file is running). –  Chris Marisic Feb 3 '11 at 18:57
    
@Chris-Marisic: Try running the batch file from outside the directory where it is located. If you cd to the directory containing the batch file and run it from there, you'll get "The process cannot access the file because it is being used by another process" even if you use /XF to exclude the batch file. –  CheeseInPosition Feb 5 '11 at 19:46
add comment

I know this is an old post but I ran into the same problem and just fixed it with the "MKDIR" command after i have run the robocopy.

You want to move all the content of a given folder, so that ONLY the parent folders is left behind. Well why not just create the parent folder again. Of cause you can have some user rights issues, but that can be solved as well.

Just my thoughts on the subject

/Henrik F

share|improve this answer
add comment

Sorry, for bringing up an old question. I have just performed a test using the /mov & /e switch, and it works perfectly. Noting from the command line options, there is a difference between /mov and /move. The test file moved across to the destination, leaving the directory structure on the source intact.

share|improve this answer
add comment

Use the /mov switch instead of /move

share|improve this answer
2  
It was suggested before (serverfault.com/questions/167723/…) and didn't work. –  sysadmin1138 May 20 '11 at 11:41
2  
It works. I'm doing it right now!!!! How arrogant of you to say it doesn't work without actually "trying" it!!! –  John Homer Mar 15 '12 at 15:26
1  
It does not work. /mov will leave the subdirectories in place, not just the parent directory. –  HugoRune Oct 5 '12 at 9:56
add comment

"My" solution is to move files and folders inside a temporary folder in the source folder. (do not copy the temporary folder to it self !) And after move this one to the taget folder.

set Source=I:\_Test\ToArchive
set target=I:\_Test\Archive
set tempFolderName=@_Copy_in_progress_Do_not_use_@
set LogFile=robocopy-result.log

robocopy.exe %source% %source%\%tempFolderName% /E /MOVE /NS /NP /v /W:0 /R:0 /LOG:%LogFile% /XD %source%\%tempFolderName%
sleep 5
robocopy.exe %source%\%tempFolderName% %target% /E /MOVE /NS /NP /v /W:0 /R:0 /LOG+:%LogFile%

I just detect that the "move" to the temporary folder takes too much time. Here the update :

set Source=I:\_Test\ToArchive
set target=I:\_Test\Archive
set tempFolderName=@_Copy_in_progress_Do_not_use_@
set LogFile=robocopy-result.log

mkdir %source%\%tempFolderName%\
for /f "delims==" %%I IN ('dir "%source%" /B') do if NOT %%I==%tempFolderName% (move "%source%\%%I" "%source%\%tempFolderName%")
sleep 3
robocopy.exe %source%\%tempFolderName% %target% /E /MOVE /NS /NP /v /W:0 /R:0 /LOG:%LogFile%
share|improve this answer
add comment

I got lucky finding the answer. I wanted to move a folder to the top level of a disk. I tried:

Robocopy "<PathToFolderToMove>" "H:\" /MOVE /E

It gave an error using the following for destination: H:\" \MOVE \E\.

I guessed that the "\" was escaping the following double quote, and I changed the command to:

Robocopy "<PathToFolderToMove>" "H:\." /MOVE /E

It ended up copying the content of "" into the root of the drive.

So the anwser to the question is:

Robocopy "c:\Users\files\Desktop\test 2" "c:\Users\files\Desktop\test\." /MOVE /E

Regards,
Georges

share|improve this answer
add comment

Create a unique placeholder file which you exclude from the robocopy command.

One liner is a s follows:

echo.>>"C:\Source\.touch" && (robocopy "C:\Source" "C:\Dest" /XF ".touch" /MOVE /E & del "C:\Source\.touch")
share|improve this answer
add comment

Why is it different? It's not different. A move operation is a copy\delete operation, whether you use Robocopy or not. You're telling it to move the folder. Moving means you move into the new location and vacate the previous location.

share|improve this answer
    
but that's not what i want. i want to move the content of the folder, keeping the folder. here how it works, unix style: (edit, no code in comments, so as a screenshot) screencast.com/t/YTkwODIzZT –  perler Aug 6 '10 at 18:39
    
-1 for blame the user answer for legitimate question –  Chris Marisic Feb 3 '11 at 18:53
    
@Chris: I don't understand. How am I blaming the user? He asked a question and I answered it. I don't see a hint of blaming in my answer. –  joeqwerty Feb 3 '11 at 21:54
    
Why is it different? It's not different. the OP posted a screen shot showing the expected behavior as it could be done through *nix but that robocopy does not seem to allow in any facet. –  Chris Marisic Feb 3 '11 at 22:14
    
C'mon guys, really? Arguing over this? I've cleaned up the question to remove the "offending" (and loaded) sentence. –  Mark Henderson Feb 6 '11 at 2:39
show 1 more comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.