Why does my defined resource refuse to copy source files listed in an array?

Question

I am attempting to populate some configuration files from modules/apt_config/files using a defined resource and an array of files to install.

define aptfile($file) {
    file { $file: source => "puppet:///modules/${module_name}/etc/apt/${file}", }
}
aptfile{ [ 'apt.conf', 'sources.list', ]: }

According to this bug report, $module_name should be available. That part isn't causing me grief. What seems to be broken is that way that $file is not being populated when I call the resource; instead, I get the following error:

Must pass file to Apt_config::Aptfile[apt.conf] at /tmp/vagrant-puppet/modules-0/apt_config/manifests/init.pp:10 on node vagrant.home

Note that line 10 is the line containing the define aptfile definition.

The syntax is a little arcane. So, just in case I was specifying the file path backwards, I also tried this:

define aptfile($file) {
    file { "/etc/apt/${file}":
        source => "puppet:///modules/${module_name}/${file}",
    }
}
aptfile{ [ 'apt.conf', 'sources.list', ]: }

with identical results. I know I could specify each file individually, but what do I need to do to make this loop work properly?

Answer 1

$file is an attribute. If you want to use the name of an instance of the definition (one of the items in the array you're using when declaring aptfile) you'd use $name.

So if you kept things as they are you'd do something like this:

aptfile {'somename':
  file => ['apt.conf', 'sources.list'],
}

However, what you're probably looking for is something like this:

define aptfile(
  $base_path = '/etc/apt',
) {
  file {"${base_path}/${name}":
    source => "puppet:///modules/${module_name}/files/${name}",
  }
}

Note that $name comes from the title/name of the resource (define is essentially a custom resource of sorts) when you declare it. The applies to all resources. When you use an array when declaring a resource file {['f1.txt', 'f2.txt']: } you are simply condensing the declaration of multiple file resources...file {'f1.txt': }, file {'f2.txt': }. $name inside the body is the name of resource declaration in play while it's being parsed/processed.

Then call it like you were:

aptfile {['apt.conf', 'sources.list']: }

I find myself just using templates with content => template('modulename/somefile.erb') even if I don't need template functionality just because the path is more sane (with minimal additional overhead I imagine). Looking forward to source => adopting the same more reasonable path usage.

Mark