4

I am trying to find a good way to deploy Lync 2013 standard & basic clients silently on computers with Windows 7 / Office 2010 & ahve a few roadblocks.

1) I am successful installing the standard client (downloaded from VL), but when installing it automatically I am getting the error "The language of this installation package is not supported by your system". I am using the syntax:

setup.exe /adminfile lyncstd.msp /config lync.ww\config.xml

I made the MSP using setup /admin and gave it a full install. I also made the config.mxl file with the following syntax:

<Configuration Product="Lync">

<Display Level="none" CompletionNotice="yes" SuppressModal="yes" AcceptEula="yes" />

<Logging Type="verbose" Path="%temp%" Template="Microsoft Office Lync Setup(*).txt" />

<USERNAME Value="Me" />

<COMPANYNAME Value="My company" />

<INSTALLLOCATION Value="%programfiles%\Microsoft Office" />

<DistributionPoint Location="\\vm-fs\public\Lync\Standard" />

<OptionState Id="LOBiMain" State="absent" Children="force" /> -->

<Setting Id="SETUP_REBOOT" Value="IfNeeded" />

So this makes no sense to me - as in why installing from the GUI would present no such problem, but automating suddenly throws up a burning hemorrhoid. In the install log, I see towards the end a message: The language of this installation package is not supported by your system", so I have tried disabling options for language support in the admin install mode as well as to Remove the following earlier version of "Microsoft Office Multi-language User Interface Pack".

2) Or is the only way to install it using a GPO running a batch file in Computer Configuration > Policies > Windows Settings > Scripts, and have it run a silent install using setup.exe with the adminfile & configfile tags?

Thanks!

1
  • The Lync 2013 install has known issues with MSP deployment. I have a working deployment scenario/ setup that I can post when I have some more time tonight.
    – HostBits
    Jul 9, 2014 at 21:24

1 Answer 1

1

In order to get around the issues with deployment using an MSP file, You can use a startup script to call the exe directly and utilize the xml config for additional parameters/ logging.

To start, create a share folder and put the Lync 2013 files in it. Make sure you give "domain computers" rights to read and write to this folder (write if you want logging) and give it both NTFS and Share permissions.

If you want logging (and you do), create a folder for the logs in the Install folder. I named mine InstallLogFiles (yup, very creative).

In the installation folder, there is the lync.www folder with the config.xml file. Edit the file and include the following:

<Display Level="none" CompletionNotice="no" SuppressModal="yes" AcceptEula="yes" />

<Logging Type="standard" Path="\\SERVER\SHARE\InstallLogFiles" Template="%computername%-Install_Log.txt" />

<!-- <USERNAME Value="Customer" /> -->

<!-- <COMPANYNAME Value="MyCompany" /> -->

<!-- <INSTALLLOCATION Value="%programfiles%\Microsoft Office" /> -->

<!-- <LIS CACHEACTION="CacheOnly" /> -->

 <LIS SOURCELIST="\\SERVER\SHARE" /> 

 <DistributionPoint Location="\\SERVER\SHARE" /> 

<!-- <OptionState Id="OptionID" State="absent" Children="force" /> -->

<Setting Id="SETUP_REBOOT" Value="never" />

<!-- <Command Path="%windir%\system32\msiexec.exe" Args="/i \\server\share\my.msi" QuietArg="/q" ChainPosition="after" Execute="install" /> -->

You can change the other values as needed, but the lines with the \SERVER\SHARE\ should point to your installation folder.

Next, you will need a startup script to run on the workstations to call the installation. The following code and be edited as needed and saved as a .bat file. The file should then be added to a Group Policy as a startup script. To make deployment easier, you can scope the policy to only be readable by an AD group. You can then add the computers who should get the install to the AD group.

Code:

setlocal

REM *********************************************************************
REM Environment customization begins here. Modify variables below.
REM *********************************************************************

REM Get ProductName from the Office product's core Setup.xml file, and then add "office15." as a prefix.
set ProductName=Office15.LYNC

REM Set DeployServer to a network-accessible location containing the Office source files.
set DeployServer=\\SERVER\SHARE

REM Set ConfigFile to the configuration file to be used for deployment (required) 
set ConfigFile=\\SERVER\SHARE\lync.WW\config.xml

REM Set LogLocation to a central directory to collect log files.
set LogLocation=\\SERVER\SHARE\InstallLogFiles

REM *********************************************************************
REM Deployment code begins here. Do not modify anything below this line.
REM *********************************************************************

REM Skip install if OS is not Win 7 or above    

IF NOT "%ProgramFiles(x86)%"=="" (goto Office2013) else (goto XP)

:Office2013
REM Check to see if Office 2013 is installed, if so Exit
reg query HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Office15.PROPLUS
echo %date% %time% Checking if Office 2013 is installed code is %errorlevel%.>> %LogLocation%\%computername%.txt
if %errorlevel%==1 (goto ARP64) else (goto End)

REM Operating system is X64. Check if Lync is already installed in emulated Wow6432 uninstall key 
:ARP64 
reg query HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432NODE\Microsoft\Windows\CurrentVersion\Uninstall\%ProductName% 
echo %date% %time% Checking if Lync is installed code is %errorlevel%.>> %LogLocation%\%computername%.txt
if %errorlevel%==1 (goto Office) else (goto End)

REM Check to see if Office 2013 is installed, if so Exit
reg query HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Office15.PROPLUS
echo %date% %time% Checking if Office 2013 is installed code is %errorlevel%.>> %LogLocation%\%computername%.txt
if %errorlevel%==1 (goto Office) else (goto End)

REM If 1 returned, the product was not found. Run setup here.

:Office
echo %date% %time% Deployment triggered on %computername%.>> %LogLocation%\%computername%.txt
start /wait %DeployServer%\setup.exe /config %ConfigFile%
echo %date% %time% Setup ended with error code %errorlevel%. &gt;&gt; %LogLocation%\%computername%.txt
exit

:XP
echo %date% %time% Machine is Windows XP - Exiting >> %LogLocation%\%computername%.txt
exit 
REM If 0 or other was returned, the product was found or another error occurred. Do nothing.
:End
exit

Endlocal

The code above will check to see if the machine is XP, if it is exit/log.
Checks to see if Office 2013 is already installed, if so exit/log.
Checks to see if Lync 2013 Standalone is already install, if so exit.

If it's not, it kicks off the install and logs it's steps. The actual Software installation log will also exist and both are set to use the %computername% variable to help trace issues.

I have deployed Lync to hundreds of machines this way, without issue.

5
  • I feel like I am very close here. The log reports: Thu 07/10/2014 9:12:16.52 Checking if Office 2013 is installed code is 1. Thu 07/10/2014 9:12:16.55 Checking if Lync is installed code is 1. Thu 07/10/2014 9:12:16.55 Deployment triggered on VM-W7TEST.
    – user228832
    Jul 10, 2014 at 14:13
  • And I see a "Setup can't find or validate an installation file. Please try reinstalling office from your installation source..." message
    – user228832
    Jul 10, 2014 at 14:14
  • Are you sure the installation files all have "Domain Computers" on their ACL?
    – HostBits
    Jul 10, 2014 at 14:34
  • Aha, never mind, my config.xml was bad. I took one from the default and edited that. Thank you thank you thank you!!! Will paste the code in the next section comment
    – user228832
    Jul 10, 2014 at 15:55
  • Ach - comment field isnt big enough here
    – user228832
    Jul 10, 2014 at 15:57

You must log in to answer this question.

Not the answer you're looking for? Browse other questions tagged .