Restart a Windows service remotely (stop/start only if already started)

Question

I'm currently using the following BAT file to restart a remote service:

sc \\MyServer stop MyRemoteService
sc \\MyServer start MyRemoteService

This works great for one computer, but I want to use it to restart services in a farm. I could just list every server in my batch file, but I only want to restart services if they're already running. For example, if the service is running on one server in the farm, restart it, but if it's not already running, then leave it stopped.

Is there any way to accomplish this remotely? I'm not married to SC is there's another program that does this.

Answer 1

This is a little more verbose than Izzy's answer, but allows for a longer duration for the service in the "STOP_PENDING" state.

Assume servers in a textfile specified on the command line, of the format:

SERVERNAME1
SERVERNAME2
...

And the script:

@echo off
set SVC=ServiceName
if "%1"=="" goto end

for /f %%i in (%1) do call :do_bounce %%i
goto end

:do_bounce
rem Query for service running and bail if not
sc \\%1 query %SVC% | find "RUNNING"
if errorlevel 1 goto end

rem Stop the service and loop checking for it to stop
sc \\%1 stop %SVC%
:check_stopped
ping 127.0.0.1 -n 2 >NUL 2>NUL
sc \\%1 query %SVC% | find "STOPPED"
if errorlevel 1 goto check_stopped

rem Restart the service
sc \\%1 start %SVC%

:end

Answer 2

This is such a dirty answer to the question it cheered me up :)

sc \\MyServer query MyRemoteService | find "RUNNING" && echo Service running - now stopping && sc \\MyServer stop MyRemoteService && ping 127.0.0.1 -n 10 && echo Now starting service && sc \\MyServer start MyRemoteService || echo Service not running

Answer 3

Powershell 2.0 has a Restart-Service commandlet

Answer 4

You might want to check out this question over on StackOverflow.

It mentions why you might want to consider doing the monitoring from each individual machine (with a windows service monitoring tool), versus relying on the network.