12

I have scheduled backup script that makes the database dump. How can I add the date timestamp to the file name?

I am talking about Windows and CMD.

20

In the command prompt and batch files, you can use %date% and %time% to return the date and time respectively. Date works fine, but the time value returned contains colons, which are illegal for use in filenames, but there is a way to remove those.

Use something like:

COPY file.txt file_%time:~0,2%%time:~3,2%%time:~6,2%_%date:~-10,2%%date:~-7,2%%date:~-4,4%.txt

This will produce a filename such as file_172215_01062009.txt

Update: The comments below have interesting twists on this command as well as some potential problems you can avoid.

  • 3
    Great little tip. BTW, if you do it the other way around, that is: "file_20090601_172215", you will see the files in the correct order in an alphabetic list. – TonJ Jun 1 '09 at 13:00
  • 5
    You can also use %time::=% to remove the colons. – grawity Jun 1 '09 at 13:33
  • 2
    I'd say that date substring-ing would break as soon as the system locale differs from when the script was tested? It could even work for the testing user and break as the script runner because of different date display formats set... – Oskar Duveborn Jun 1 '09 at 18:17
  • 3
    Beware hours 0 - 9! CMD sets the first character of the hour to <SPACE>, rather than 0. The COPY command above is going to have problems if you don't enclose the destination filename in quotes. – Evan Anderson Jun 1 '09 at 20:09
  • 2
    Note that %DATE% and %TIME% are locale-aware! It means that on a European machine, you get DD.MM.YYYY. Arrgh. – Pekka 웃 Jan 26 '11 at 20:36
14

Use the %DATE% and/or %TIME environment variables, optionally substituting the characters that are not allowed in filenames, using %name:from=to% (%TIME::=% would remove all colons).

theory » echo %date%
2009-06-01

theory » echo %time%
16:30:41,46

theory » echo %time::=%
163052,17

theory » echo %time::=,%
16,30,58,68

theory » echo backup-%date%-%time::=-%.zip
backup-2009-06-01-16-31-18,82.zip
  • 1
    wow, never know about the :x=y trick. that's really cool. – Eugene Katz Jun 1 '09 at 21:37
  • 1
    +1 for the := trick, iv'e been in this game since MS-Dos 1 and that's the first time Iv'e seen that one. Would be even better if you could change multiple chars too!! :-) – shawty Sep 17 '18 at 12:02
  • Well, it was only added to Cmd.exe in the Windows NT series... And if you want to perform multiple changes, just have a chain of set tmp=%tmp:x=y% etc. – grawity Sep 17 '18 at 12:12
  • The content of %DATE% (number of fileds, content and ordering) are locale specific. – symcbean Apr 4 at 13:26
3

The only reliable way to get appropriate date whatever regional setting are is the solution of foxidrive @ https://stackoverflow.com/questions/11037831/filename-timestamp-in-windows-cmd-batch-script

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%"
set "fullstamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause
1

Use %DATE% variable in the filename.

There is a %TIME% variable as well, but it contains characters not allowed in a file name.

Here is an example of writing a line of text into a new file, where the file created has a date and time in its name.

echo "testfile" >> backup-%DATE%.txt

protected by Michael Hampton Aug 14 '15 at 0:14

Thank you for your interest in this question. Because it has attracted low-quality or spam answers that had to be removed, posting an answer now requires 10 reputation on this site (the association bonus does not count).

Would you like to answer one of these unanswered questions instead?

Not the answer you're looking for? Browse other questions tagged or ask your own question.