1

Hi Guys I have WSUS server and is working fine with active diectory. but how can I connect workgroup pcs running on windows xp to WSUS without joining them to AD? Thank you in advance.

1

I use the following batch script to flip-flop systems on and off WSUS. It works great to quickly get formatted systems updated before we give them away.

Change [SERVER] to your WSUS server under the :USEWSUS section.


@echo off
:START
cls
echo Temporary WSUS Script
echo ==============================
echo This script will flip between using the internal WSUS server and Microsoft's servers.
echo.
set /p WSUSSETTING=Type [W] to use WSUS or [C] to clear the setting and use MS servers: 

IF /i (%WSUSSETTING%) == (W) goto CONTINUE
if /i (%WSUSSETTING%) == (C) goto CONTINUE

echo.
echo Error: Invalid selection
pause
goto START

:CONTINUE
echo Stopping Update Services...
net stop wuauserv
echo Deleting timeout registry entries (Safe to ignore errors)...
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v LastWaitTimeout /f
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v DetectionStartTime /f
reg delete "HKLM\Software\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update" /v NextDetectionTime /f

IF /i (%WSUSSETTING%) == (W) goto USEWSUS
IF /i (%WSUSSETTING%) == (C) goto USEMS

:USEWSUS
echo Changing update server to local WSUS server...
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUServer /t REG_SZ /d "http://[SERVER]:8530" /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUStatusServer /t REG_SZ /d "http://[SERVER]:8530" /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v NoAutoUpdate /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v AUOptions /t REG_DWORD /d 3 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v AutoInstallMinorUpdate /t REG_DWORD /d 1 /f
reg add "HKEY_LOCAL_MACHINE\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v UseWUServer /t REG_DWORD /d 1 /f
goto COMPLETE

:USEMS
echo Clearing WSUS update server...
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUServer /f
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v WUStatusServer /f
reg delete "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate\AU" /v UseWUServer /f
goto COMPLETE


:COMPLETE
echo Starting Update Services...
net start wuauserv

:END
echo ---
echo Complete.
pause
2

You can make the same changes required by updating the registry directly; a quick search brought me to this link which looks like it has the correct information. If not, a little bit more thorough search on your part will likely get you the information you're missing.

0

If it is Professional Edition, you can use local Group Policy as well. Run gpedit.msc and browse to "Computer Configuration -> Administrative Templates -> Windows Components -> Windows Update".

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.